koobas.hobune.stream
Add Alpha Support for Fog Shader
Hi, I have this Fog Shader for WP8 and I'm pretty new to shaders so I've implemented material coloring but I need to make it support transparency like Transparent/Cutoff/Diffuse shader does or really any transparent supporting shader. Can you please help me?
Shader "Custom/Fog" {
Properties {
_MainTex ("Base (RGB)", 2D) = "white" {}
_Color ("Main Color", Color) = (1, 1, 1, 1)
}
SubShader {
Tags { "RenderType"="Opaque" }
Fog {Mode Off}
LOD 200
CGPROGRAM
#pragma surface surf Lambert vertex:fogVertex finalcolor:fogColor
sampler2D _MainTex;
float4 _Color;
uniform half4 unity_FogColor;
uniform half4 unity_FogStart;
uniform half4 unity_FogEnd;
uniform half4 unity_FogDensity;
struct Input {
float2 uv_MainTex;
half fogFactor;
};
void fogVertex(inout appdata_full v, out Input data)
{
UNITY_INITIALIZE_OUTPUT(Input, data);
float cameraVertDist = length(mul(UNITY_MATRIX_MV, v.vertex).xyz);
data.fogFactor = saturate((unity_FogEnd.x - cameraVertDist) / (unity_FogEnd.x - unity_FogStart.x));
}
void fogColor(Input IN, SurfaceOutput o, inout fixed4 color)
{
color.rgb = lerp(unity_FogColor.rgb, color.rgb, IN.fogFactor) * _Color;
}
void surf (Input IN, inout SurfaceOutput o) {
half4 c = tex2D (_MainTex, IN.uv_MainTex);
o.Albedo = c.rgb;
o.Alpha = c.a;
}
ENDCG
}
FallBack "Diffuse"
}
Best Answer
Never mind, just found out how to modify this shader to do it. Here's the code:
Shader "Custom/FogShader" {
Properties {
_MainTex ("Base (RGB)", 2D) = "white" {}
_Color ("Color", Color) = (1, 1, 1, 1)
_Cutoff ("Alpha cutoff", Range(0,1)) = 0.5
}
SubShader {
Tags {"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
Fog { Mode Off }
LOD 200
CGPROGRAM
#pragma surface surf Lambert vertex:fogVertex finalcolor:fogColor alphatest:_Cutoff
sampler2D _MainTex;
uniform half4 unity_FogColor;
uniform half4 unity_FogStart;
uniform half4 unity_FogEnd;
uniform half4 unity_FogDensity;
uniform half4 _Color;
struct Input {
float2 uv_MainTex;
half fogFactor;
};
void fogVertex(inout appdata_full v, out Input data)
{
UNITY_INITIALIZE_OUTPUT(Input, data);
float cameraVertDist = length(mul(UNITY_MATRIX_MV, v.vertex).xyz);
float f = cameraVertDist * unity_FogDensity;
data.fogFactor = saturate(1 / pow(2.71828, f * f));
}
void fogColor(Input IN, SurfaceOutput o, inout fixed4 color)
{
color.rgb = lerp(unity_FogColor.rgb, color.rgb, IN.fogFactor);
}
void surf (Input IN, inout SurfaceOutput o) {
half4 c = tex2D (_MainTex, IN.uv_MainTex);
o.Albedo = c.rgb * _Color;
o.Alpha = c.a;
}
ENDCG
}
FallBack "Diffuse"
}
