- Home /
Sprite obstruction transparent area
I am trying to build a system in my game that will make sprite tiles that are in front of my character semi-transparent. It is simple enough to adjust the alpha channel on the sprite renderer material but the problem with that is the tile borders then become very apparent and is pretty ugly. What I would like to do is have a way to feed it a beginning and end value for alpha so I can have it create a nice alpha gradient along the x axis. How might I go about this? Do I create a custom shader? Any examples? I have googled this until I was blue in the face but I must not be searching for the right thing because could not find anything.
Thanks!
Answer by zboyet · Aug 08, 2014 at 10:56 PM
Ok, after bouncing my head off this task for awhile I think I have nailed what I need so I will share with the class.
Here is my modified sprite shader
Shader "Sprites/AlphaGradient"
{
Properties
{
[PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
_Color ("Tint", Color) = (1,1,1,1)
[MaterialToggle] PixelSnap ("Pixel snap", Float) = 0
[MaterialToggle] _UseFade ("Use Fade", Float) = 0
_FadeOrigin ("Fade Origin", vector) = (1,1,1)
_FadeAreaMin ("Fade Area Min", float) = 1.5
_FadeAreaMax ("Fade Area Max", float) = 2.5
_MaxOpacity ("Max Opacity", Range(0,1)) = 0.5
}
SubShader
{
Tags
{
"Queue"="Transparent"
"IgnoreProjector"="True"
"RenderType"="Transparent"
"PreviewType"="Plane"
"CanUseSpriteAtlas"="True"
}
Cull Off
Lighting Off
ZWrite Off
Fog { Mode Off }
Blend One OneMinusSrcAlpha
Pass
{
CGPROGRAM
#pragma vertex vert
#pragma fragment frag
#pragma multi_compile DUMMY PIXELSNAP_ON
#include "UnityCG.cginc"
struct appdata_t
{
float4 vertex : POSITION;
float4 color : COLOR;
float2 texcoord : TEXCOORD0;
};
struct v2f
{
float4 vertex : SV_POSITION;
float4 objCoords : TEXCOORD1;
fixed4 color : COLOR;
half2 texcoord : TEXCOORD0;
};
fixed4 _Color;
v2f vert(appdata_t IN)
{
v2f OUT;
OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
OUT.objCoords = mul(_Object2World, IN.vertex);
OUT.texcoord = IN.texcoord;
OUT.color = IN.color * _Color;
#ifdef PIXELSNAP_ON
OUT.vertex = UnityPixelSnap (OUT.vertex);
#endif
return OUT;
}
sampler2D _MainTex;
float _UseFade;
float _FadeAreaMin;
float _FadeAreaMax;
vector _FadeOrigin;
float _MaxOpacity;
fixed4 frag(v2f IN) : SV_Target
{
fixed4 c = tex2D(_MainTex, IN.texcoord) * IN.color;
float percent = 1;
if(_UseFade == 1)
{
float pixDist = distance(_FadeOrigin.xy, IN.objCoords.xy);
if(pixDist < _FadeAreaMin)
{
percent = _MaxOpacity;
}
else
{
if(_FadeAreaMin > _FadeAreaMax)
{
_FadeAreaMin = _FadeAreaMax;
}
if(_FadeAreaMax < _FadeAreaMin)
{
_FadeAreaMax = _FadeAreaMin;
}
if(pixDist > _FadeAreaMin && pixDist < _FadeAreaMax)
{
float fadeAreaSize = _FadeAreaMax - _FadeAreaMin;
float pixPos = pixDist - _FadeAreaMin;
float fadePercent = pixPos/fadeAreaSize;
if(fadePercent < _MaxOpacity)
{
fadePercent = _MaxOpacity;
}
percent = fadePercent;
}
}
}
c.rgba *= c.a * percent;
return c;
}
ENDCG
}
}
}
And below is how it looks. It will create a fade effects from the origin point. I hope this helps some people because for this shader noob it was quite a challenge.
Hello, Can you please explain how you integrated this shader into your scene hieararchy?
Thanks!
Your answer
Follow this Question
Related Questions
Created Material Shows Dark Sprite 1 Answer
Shader Edit Help: 2D Outline Coloring 2 Answers
Create sprite renderer using custom material 2 Answers
Changing Eye Colour (Colour only non-white parts of a texture?) 2 Answers
How can i get my quad to only render my texture without stretching it? 1 Answer